1 GOSUB 60100:PRINT"[147]"
2 POKE 53280,0:POKE 53281,0
4 GOSUB 320:PRINT CL$
6 PRINT G$ SPC(3)"YOU ARE AN INTELLIGENCE ANALYST"
8 PRINT SPC(10)"AT THE SUPERSECRET"
10 PRINT SPC(3)"NATIONAL SECURITY ADMINISTRATION"
12 PRINT:PRINT"YOUR TASK:"
14 PRINT B$ SPC(5)"LOCATE A CLANDESTINE RADIO STATION"
16 PRINT SPC(5)"OPERATED BY A TERRORIST GROUP."
18 PRINT G$"YOUR MEANS:"
20 PRINT B$ SPC(5)"SOPHISTICATED, COMPUTER ASSISTED"
22 PRINT SPC(5)"RADIO DETECTION EQUIPMENT."
24 PRINT G$"YOUR OPERATIONAL PROCEDURE:"
26 PRINT B$ SPC(5)"1. IDENTIFY THIS COVERT STATION"
28 PRINT SPC(8)"WHICH IS TRANSMITTING ON AN"
30 PRINT SPC(8)"ILLEGAL RADIO FREQUENCY."
36 PRINT B$ SPC(5)"2. IF AND WHEN YOU THINK YOU HAVE"
38 PRINT SPC(8)"IDENTIFIED IT, PRESS THE * KEY."
40 PRINT G$ "EVALUATION OF RESULT:"
42 PRINT B$ SPC(5)"IF YOU ARE CORRECT, THE TERRORISTS"
44 PRINT SPC(5)"WILL BE CAUGHT IN TIME."
46 GOSUB 362
48 PRINT G$"BUT, IF YOU ARE WRONG OR TAKE TOO MUCH"
50 PRINT"TIME -- B O O M --"
52 PRINT:GOSUB 434
53 GOSUB330
54 PRINT"          PRESS SPACE TO START":POKE198,.
58 IFPEEK(203)<>60THEN58
60 TI$="000000"
62 PRINT CL$:K$=""
64 X=INT(RND(0)*30)+1
66 XX=INT(RND(0)*5)+1:GOTO 124
68 PRINT U$ U2$ L2$:PRINT L2$
70 PRINT TAB(X+4) U2$ W$ CHR$(161)
72 PRINT TAB(X+4) CHR$(161)
74 PRINT E$ L6$:RETURN
76 POKE S+24,15:POKE S+5,0
78 POKE S+6,240:POKE S,75:POKE S+1,34
80 AL$=MID$(A1$,I,1)
82 IF AL$="."THEN GOSUB 100:RETURN
84 IF AL$="-"THEN GOSUB 104:RETURN
86 IF AL$="A"THEN GOSUB 100:GOSUB 104
88 IF AL$="B"THEN GOSUB 104:GOSUB 100:GOSUB 100:GOSUB 100
90 IF AL$="E"THEN GOSUB 100
92 IF AL$="O"THEN GOSUB 104:GOSUB 104:GOSUB 104
94 IF AL$="M"THEN GOSUB 104:GOSUB 104
96 IF AL$="T"THEN GOSUB 104
98 RETURN
100 POKE S+4,17:FOR D=1 TO 20:NEXT
102 POKE S+4,16:FOR D=1 TO 20:NEXT:RETURN
104 POKE S+4,17:FOR D=1 TO 80:NEXT
106 POKE S+4,16:FOR D=1 TO 80:NEXT:RETURN
108 POKE S+6,241:POKE S+4,33:POKE S+1,21
110 FOR J=0 TO 15 STEP 3:POKE S+24,J:NEXT
112 FOR J=1 TO 10:NEXT:POKE S+4,32:POKE S+24,0:RETURN
114 POKE S+24,15:POKE S+1,110:POKE S+5,9
116 POKE S+6,9:POKE S+4,17:POKE S+4,16:RETURN
118 FOR J=1 TO 20:POKE S+24,15
120 FOR T=1 TO 3:NEXT:POKE S+24,0
122 FOR T=1 TO 3:NEXT:NEXT:RETURN
124 R%=0:R$="":IF TI$<"000500"THEN 132
126 POKE 53281,2:POKE 53280,10
128 PRINT CL$:GOSUB 118
130 PRINT"YOUR TIME IS UP"TAB(255) W$"B O O M":GOTO 542
132 IF RIGHT$(C$(R),1)="?"THEN C$(R)=LEFT$(C$(R),LEN(C$(R))-1)
134 Y=INT(RND(0)*6)+1:R=X+XX
136 IF R>30 THEN R=R-30
138 IF X<0 OR X>30 THEN X=0
140 IN=0:PRINT""
144 GOSUB2000:PRINT" [159]AFTER THE TRANSMISSION HAS ENDED,"
146 PRINT"YOU CAN ASK FOR INTELLIGENCE ANALYSIS."
148 PRINT" [154]WHEN YOU THINK YOU HAVE IDENTIFIED"
150 PRINT"THE TERRORIST, PRESS * KEY FOR RADAR"
151 PRINT"RANGING"
152 PRINT CHR$(19);
154 PRINT Z$ W$ S2$"<-CURSOR->";
156 PRINT S2$ S2$"MOVES DIAL AT ANY TIME"S$
158 PRINT E$ L4$
160 PRINT S$ CHR$(180) S$"7.0"SPC(7)"7.1";
162 PRINT SPC(7)"7.2"SPC(7)"7.3"S$ CHR$(167)
164 PRINT L2$:PRINT L2$:PRINT L6$
166 GOSUB 68
168 F=(7+X/100):F$=STR$(F)+"0"
170 IF LEN(F$)<6 THEN F$=F$+"0"
172 IF X=0 THEN F$="7.000"+S$
174 PRINT:PRINT
176 IF R>13 AND R<18 THEN Y=6
178 IF Y<5 THEN C$(R)=C$(R)+D$+"?":R$=S2$+G$+CHR$(119)
180 IF Y<3 THEN R$=S2$+E$+CHR$(123)
182 PRINT N$ S$ L8$ S2$ R8$ S2$ L8$
184 F1$=B$+"FREQUENCY:":IF R%=1 THEN F1$=E$+"TIME TAKEN"
186 PRINT S$ CHR$(180) S$ F1$ N$ CHR$(167);
188 PRINT TAB(16) G$ CHR$(180)"RADAR"G$ CHR$(167);
190 F2$=B$+S$+"CALL SIGN:":IF R%=1 THEN F2$=E$+"R E S U L T"
192 PRINT TAB(25) N$ CHR$(180) F2$ N$ CHR$(167):IF R%=0 THEN 198
194 PRINT S$ T$ S2$ CHR$(180) R$ TAB(22) N$ CHR$(167);
196 PRINT TAB(25) CHR$(180) TAB(28) YR$ TAB(37) CHR$(167):GOTO 204
198 PRINT S$ CHR$(180) F$ S$"MHZ"S$ CHR$(167);
200 PRINT TAB(16) G$ CHR$(180) R$ TAB(22) G$ CHR$(167);
202 PRINT TAB(25) N$ CHR$(180) TAB(28) C$(R) TAB(37) N$ CHR$(167)
204 PRINT N$ S$ L0$ S2$ R0$ S2$ L0$
206 GOSUB 210:IF R%=1 THEN RETURN
208 GOTO 222
210 H1$=N$:H$=B$+"TRANSMISSION BEING RECEIVED:"+S2$+H1$
212 IF K$="I"THEN H$="INTELLIGENCE ANALYSIS REVEALS:":H1$=D$
214 PRINT:PRINT H1$ L4$
216 PRINT S$ CHR$(180) TAB(5) H$ TAB(37) CHR$(167)
218 PRINT S$ CHR$(180) LEFT$(LL$,35) TAB(37) CHR$(167)
220 PRINT L6$:PRINT U2$;:RETURN
222 A%=0:A2$="":Y$="":IF R>13 AND R<18 THEN A%=1
224 IF R>17 AND R<26 THEN A%=2
226 IF Y=1 THEN Y$=Y1$
228 IF Y=2 OR Y=3 THEN Y$=Y2$
230 A1$=A$(R)+Y$:A1=LEN(A1$)
232 IF A1<34 THEN 238
234 A2$=RIGHT$(A1$,A1-33)
236 A2=LEN(A2$)
238 FOR I=1 TO A1+1
240 A3$=MID$(A2$,I,1)
242 AA$=MID$(A1$,I,33)+A3$
244 PRINT TAB(2) AA$ S$ U$
246 IF A%=0 THEN 258
248 IF A%=2 THEN 254
250 IF I=1 OR I=8 THEN GOSUB 118
252 IF A%=1 THEN 260
254 IF I=2 OR I=12 THEN GOSUB 114
256 IF I=20 OR I=36 THEN GOSUB 114
258 IF A%=0 OR Y<4 THEN GOSUB 76
260 IF I=1 THEN FOR JJ=1 TO 50
262 IF PEEK(203)=49 THEN 490
264 IF PEEK(203)<>2 THEN 270
266 IF (PEEK(653)AND1)=1  THEN X=X-1:GOTO 124
268 IF (PEEK(653)AND1)=0 THEN X=X+1:GOTO 124
270 IF I=1 THEN NEXT JJ
272 NEXT I
274 PRINT:PRINT
276 GOSUB2000
280 IF IN<2 THEN 286
282 PRINT U$ SPC(8) Z$ E$"TIME FOR A DECISION"
284 PRINTLL$:GOTO 288
286 PRINT N$"PRESS"S$ Z$ W$"R"RF$ N$ S$"TO REPLAY TRANSMISSION"
288 PRINT N$"PRESS"S$ Z$ W$"I"RF$ S$ Z$ D$ S$"FOR INTELLIGENCE ANALYSIS"
290 PRINT N$"OR MOVE"S$ Z$ W$"<-CURSOR->"RF$ N$ S2$"TO CHANGE FREQUENCY"
292 FOR J=1 TO 10:GET K$:NEXT
294 GOSUB 108
296 GET K$:IF K$=""THEN FOR J=1 TO 700:NEXT:GOTO 294
298 IF ASC(K$)=29 OR ASC(K$)=157 THEN 266
300 IF K$="*"THEN 490
302 FOR J=1 TO 5:PRINT U$;:NEXT
304 GOSUB2000:PRINT""
306 FOR J=1 TO 4:PRINT U2$;:NEXT
308 GOSUB 210:IF K$<>"I"THEN 230
310 IF Y>3 THEN 316
312 IF IN=0 THEN PRINT TAB(2) Y3$:IN=IN+1:PRINT U$:GOTO 318
314 IF Y<3 THEN PRINT TAB(2) E$ Y5$ LP$ N$:IN=IN+1:PRINT U$:GOTO 318
316 PRINT TAB(2) N$ I$(R)
318 PRINT U$;:GOTO 274
320 DIM C$(30),A$(30),I$(30)
322 S=54272:U$=CHR$(145):U2$=U$+U$:CL$=CHR$(147)
324 Z$="":RF$=CHR$(146):W$=CHR$(5):D$=CHR$(150)
326 N$="[153]":B$="[154]":G$="[155]":E$="[158]"
328 RETURN
330 S$=" ":S2$=S$+S$
332 FOR J=1 TO 4:P$=P$+".":NEXT
334 L1$="[221]"+P$+":"+P$
336 L2$=S$+"[165]"+S2$+L1$+L1$+L1$+"[221]"+S2$+"[167]"
338 FOR J=1 TO 35:L3$=L3$+"[183]":L5$=L5$+"[175]":NEXT
340 L4$=S$+"[207]"+L3$+"[208]"
342 L6$=S$+"[204]"+L5$+"[186]"
344 FOR J=1 TO 11:L7$=L7$+"[183]":L9$=L9$+"[175]":NEXT
346 FOR J=1 TO 5:R7$=R7$+"[183]":R9$=R9$+"[175]":NEXT
348 L8$="[207]"+L7$+"[208]"
350 R8$=G$+"[207]"+R7$+"[208]"+N$
352 L0$="[204]"+L9$+"[186]"
354 R0$=G$+"[204]"+R9$+"[186]"+N$
356 FOR J=1 TO 37:LL$=LL$+S$:NEXT
358 FOR J=1 TO 39:L$=L$+"[183]":NEXT
360 RETURN
362 FOR J=1 TO 30:READ C$(J):NEXT
364 DATA N6NTA,N6GDM,W6NBJ,K2SNO,W4WJ,AI6I,N49DT,N5473,XE1FE,DL2SR,UR5UW
366 DATA NONE,NONE,NONE,NONE,NONE,NONE
368 DATA WIEN,ROME,PARIS,BBC,WSL,KFI,KNX,WNYC,WX-11,WX-12,LAX,CBS-TV,WWV
370 FOR J=1 TO 30:READ A$(J):NEXT
372 DATA CQ FROM NOVEMBER SIX NOVEMBER TANGO ALPHA
374 DATA THIS IS HEMET EMERGENCY OPERATIONS CENTER WITH ART ON THE MIKE
376 DATA PLEASE CLEAR THE FREQUENCY FOR EMERGENCY TRAFFIC  QSL?
378 DATA" .-.-.  ...-.-"
380 DATA EARTHQUAKE DAMAGE HERE IS LIGHT
382 DATA" -.-.  --.-  -..  .  .- .. -.... ..  -.-"
384 DATA MY ETA LAX IS 18 HOURS LOCAL TIME
386 DATA MAYDAY - FIRE IN LEFT ENGINE - REQUEST EMERGENCY CLEARANCE
388 DATA MANANA SENORITA
390 DATA SPRECHEN SIE DEUTSCH?
392 DATA STRASTVICHE TOVARICH
394 DATA" ...-  UNIDENTIFIED TRANSMISSION"
396 DATA" ...-  UNIDENTIFIED TRANSMISSION"
398 DATA NONE    NONE
400 DATA NONE    NONE
402 DATA NONE    NONE
404 DATA NONE    NONE
406 DATA GUTEN ABEND MEINE DAMEN UND HERREN
408 DATA AMORE AMORE  A RIVIDERCI
410 DATA BON JOUR MADAM ET MONSIEUR
412 DATA THIS - IS - LONDON
414 DATA MUSIC MUSIC
416 DATA MUSIC MUSIC
418 DATA HERE IS THE NEWS - BUT FIRST A COMMERCIAL
420 DATA THE TEMPERATURE WILL BE IN THE LOWER EIGHTIES
422 DATA PROBABILITY OF RAIN IS 80% TONIGHT
424 DATA FROST WARNING FOR ALL AREAS
426 DATA YOU ARE CLEARED FOR LANDING ON RUNWAY 2 WEST
428 DATA" ........."
430 DATA"THE TIME IS 14:25 UTC"
432 RETURN
434 I$(1)="HAM RADIO STATION"
436 FOR J=2 TO 6:I$(J)=I$(1):NEXT
438 I$(7)="AIRCRAFT TRAFFIC"
440 I$(8)=I$(7)
442 I$(9)="FOREIGN HAM STATION"
444 I$(10)=I$(9):I$(11)=I$(9)
446 I$(12)="SWAT TEAM COMMUNICATION"
448 I$(13)=I$(12)
450 I$(14)="NO RECEPTION ON THIS FREQUENCY"
452 FOR J=15 TO 17:I$(J)=I$(14):NEXT
454 I$(18)="FOREIGN BROADCAST STATION"
456 FOR J=19 TO 21:I$(J)=I$(18):NEXT
458 I$(22)="COMMERCIAL BROADCAST STATION"
460 FOR J=23 TO 25:I$(J)=I$(22):NEXT
462 I$(26)="WEATHER BUREAU"
464 I$(27)=I$(26)
466 I$(28)="AIRPORT CONTROL TOWER"
468 I$(29)="TELEVISION STATION"
470 I$(30)="FT COLLINS TIME SIGNAL"
472 Y1$=S2$+"-...  ---  --  -..."
474 Y2$=S2$+"-  .  .-  --"
476 Y3$="SUSPICIOUS! - REPEAT ANALYSIS ! _ _"
478 Y5$="POSSIBLE TERRORIST STATION !"
480 Y6$=W$+"SUCCESS"+S$
482 Y7$=G$+"FAILURE"+S$
484 Y8$="SWAT TEAM HELICOPTER LEAVING"
486 Y9$="SWAT TEAM IS CALLING YOU"
488 RETURN
490 R%=1:PRINT CHR$(19) L$
492 FOR J=1 TO 7:PRINT:NEXT
494 T$=MID$(TI$,3,2)+S$+"MIN"+S$+RIGHT$(TI$,2)+S$+"SEC"
496 IF Y>1 THEN POKE 53280,0:YR$=Y7$:YB$=Y9$:GOTO 500
498 POKE 53280,7:YR$=Y6$:YB$=Y8$
500 GOSUB 182
502 IF A%=1 THEN PRINT G$ TAB(10) A$(14):GOTO 508
504 IF Y=1 THEN PRINT W$ Y8$:GOSUB 114
506 IF Y>1 THEN PRINT TAB(6) G$ Y9$:GOSUB 118
508 PRINT
510 FOR J=1 TO 7:PRINT LL$ S2$:NEXT
512 FOR J=1 TO 6:PRINT U$;:NEXT
514 IF Y=1 THEN 536
516 IF A%=1 THEN PRINT I$(14):GOTO 524
518 PRINT G$"YOU MISIDENTIFIED THE CLUES."
520 PRINT"THIS WAS THE SWAT TEAM WAITING FOR YOU"
522 PRINT"TO LOCATE THE TERRORIST RADIO STATION."
524 PRINT B$ SPC(5)"CONTINUE SEARCHING (Y/N)?"
526 FOR J=1 TO 10:GET Y$:NEXT
528 GOSUB 108
530 GET Y$:IF Y$=""THEN 530
532 IF Y$="Y"THEN X=X+1:GOTO 124
534 PRINT U$ LL$:GOTO 544
536 PRINT SPC(10)"YOU WERE CORRECT !"
538 PRINT SPC(7)"END OF A SUCCESSFUL GAME."
540 PRINT B$"IT TOOK YOU"S$ T$
542 PRINT
544 PRINT B$"          ANOTHER GAME (Y/N) ?"
546 FOR J=1 TO 10:GET Y$:NEXT
548 GOSUB 108
550 GET Y$:IF Y$=""THEN 550
552 IF Y$="Y"THEN RUN2
554 PRINT"[145]                 E N D                "
556 GOTO60000
2000 FORA=217TO242:POKEA,PEEK(A)OR128:NEXT
2005 PRINT"";:FORA=1TO17:PRINT:NEXT
2010 FORA=1TO7:PRINT"                                        ":NEXT
2020 PRINT"[145][145][145][145][145][145][145]":RETURN
60000 OPEN15,8,15,"R0:HELLO CONNECT=HELLO CONNECT":INPUT#15,ER:CLOSE15
60010 IFER<>63THENEND
60020 LOAD"HELLO CONNECT",8
60100 POKE 53280,14:POKE 53281,14
60110 PRINTCHR$(142) "[147][213][192][192][192][192][192][192][192][192][192][192][192][192][192][192][192][192][192][192][192][192][192][192][192][192][192][192][192][192][192][192][192][192][192][192][192][192][192][192][201]";
60120 FORA=1TO23:PRINT"[221]"SPC(38)"[221]";:NEXT
60130 PRINT"[202][192][192][192][192][192][192][192][192][192][192][192][192][192][192][192][192][192][192][192][192][192][192][192][192][192][192][192][192][192][192][192][192][192][192][192][192][192][203][157][148][192]"
60135 FORA=217TO242:POKEA,PEEK(A)OR128:NEXT
60140 PRINT"           LOADSTAR PRESENTS:"
60150 PRINT"                               "
60160 PRINT"             RADIO SEARCH       "
60170 PRINT"                                "
60180 PRINT"          BY GERHARD SCHILLING  "
60190 PRINT"                                "
60200 PRINT"            COPYRIGHT 1987      "
60210 PRINT"                                "
60220 PRINT"                                "
60230 PRINT"        PRESS SPACE TO CONTINUE"
60240 IFPEEK(203)<>60THEN 60240
60250 RETURN